rem == CreatePartitions-UEFI.txt ==
rem == These commands are used with DiskPart to
rem    create five partitions
rem    for a UEFI/GPT-based PC.
rem    Adjust the partition sizes to fill the drive
rem    as necessary. ==

rem WinNTSetup_Boot=S:
rem WinNTSetup_Install=W:

select disk %WinNTSetup_Disk%
clean
convert gpt

rem == 1. Windows RE tools partition ===============
create partition primary size=1000
set id="de94bba4-06d1-4d40-a16a-bfd50179d6ac"
gpt attributes=0x8000000000000001
format quick fs=ntfs label="Windows RE tools"
assign letter="T"

rem == 2. System partition =========================
create partition efi size=100
rem    ** NOTE: For Advanced Format 4Kn drives,
rem               change this value to size = 260 ** 
format quick fs=fat32 label="System"
assign letter="S"

rem == 3. Microsoft Reserved (MSR) partition =======
create partition msr size=128

rem == 4. Windows partition ========================
rem ==    a. Create the Windows partition ==========
create partition primary 
rem ==    b. Create space for the recovery image ===
shrink minimum=15000
rem       ** NOTE: Update this size to match the size
rem                of the recovery image           **
rem ==    c. Prepare the Windows partition ========= 
format quick fs=ntfs label="Windows"
assign letter="W"

rem === 5. Recovery image partition ================
create partition primary
set id="de94bba4-06d1-4d40-a16a-bfd50179d6ac"
gpt attributes=0x8000000000000001
format quick fs=ntfs label="Recovery image"
rem assign letter="R"
list volume
exit
